Создать кластер PostgreSQL для 1С

Последнее изменение: 01 апреля 2025

Создать кластер PostgreSQL для 1С

Мы рекомендуем создавать ресурсы по порядку. Если вы единовременно создаете все ресурсы, которые описаны в конфигурационном файле, может возникнуть ошибка — Terraform создает ресурсы независимо от порядка, в котором они перечислены в файле.

1. Опционально: настройте провайдеры.
2. Создайте приватную сеть и подсеть.
3. Создайте кластер.
4. Создайте пользователя.
5. Создайте базу данных и назначьте владельца.

Конфигурационные файлы⁠

Пример файла для настройки провайдеров

terraform {
  required_providers {
    servercore  = {
      source  = "terraform.servercore.com/servercore/servercore"
      version = "~>6.0.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "servercore" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-9"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}

resource "servercore_project_v2" "project_1" {
  name = "project"
}

resource "servercore_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = servercore_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = servercore_project_v2.project_1.id
  user_name   = servercore_iam_serviceuser_v1.serviceuser_1.name
  password    = servercore_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Пример файла для создания кластера PostgreSQL для 1С фиксированной конфигурации

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

data "servercore_dbaas_datastore_type_v1" "datastore_type_1" {
  project_id = servercore_project_v2.project_1.id
  region     = "ru-9"
  filter {
    engine  = "postgresql"
    version = "14-1C"
  }
}

data "servercore_dbaas_flavor_v1" "flavor_1" {
  project_id = servercore_project_v2.project_1.id
  region     = "ru-9"
  filter {
    datastore_type_id = data.servercore_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
    fl_size           = "standard"
    vcpus             = 4
    ram               = 16384
    disk              = 128
  }
}

resource "servercore_dbaas_postgresql_datastore_v1" "datastore_1" {
  name       = "datastore-1"
  project_id = servercore_project_v2.project_1.id
  region     = "ru-9"
  type_id    = data.servercore_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
  subnet_id  = servercore_subnet_v2.subnet.subnet_id
  node_count = 3
  flavor_id  = data.servercore_dbaas_flavor_v1.flavor_1.flavors[0].id
  pooler {
    mode = "transaction"
    size = 50
  }
}

resource "servercore_dbaas_user_v1" "user_1" {
  project_id   = servercore_project_v2.project_1.id
  region       = "ru-9"
  datastore_id = servercore_dbaas_postgresql_datastore_v1.datastore_1.id
  name         = "user"
  password     = "secret"
}

resource "servercore_dbaas_postgresql_database_v1" "database_1" {
  project_id   = servercore_project_v2.project_1.id
  region       = "ru-9"
  datastore_id = servercore_dbaas_postgresql_datastore_v1.datastore_1.id
  owner_id     = servercore_dbaas_user_v1.user_1.id
  name         = "database_1"
}

Пример файла для создания кластера PostgreSQL для 1С произвольной конфигурации

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

data "servercore_dbaas_datastore_type_v1" "datastore_type_1" {
  project_id = servercore_project_v2.project_1.id
  region     = "ru-9"
  filter {
    engine  = "postgresql"
    version = "14-1С"
  }
}

resource "servercore_dbaas_postgresql_datastore_v1" "datastore_1" {
  name       = "datastore-1"
  project_id = servercore_project_v2.project_1.id
  region     = "ru-9"
  type_id    = data.servercore_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
  subnet_id  = servercore_subnet_v2.subnet.subnet_id
  node_count = 3
  flavor {
    vcpus = 1
    ram   = 4096
    disk  = 32
  }
}

resource "servercore_dbaas_user_v1" "user_1" {
  project_id   = servercore_project_v2.project_1.id
  region       = "ru-9"
  datastore_id = servercore_dbaas_postgresql_datastore_v1.datastore_1.id
  name         = "user"
  password     = "secret"
}

resource "servercore_dbaas_postgresql_database_v1" "database_1" {
  project_id   = servercore_project_v2.project_1.id
  region       = "ru-9"
  datastore_id = servercore_dbaas_postgresql_datastore_v1.datastore_1.id
  owner_id     = servercore_dbaas_user_v1.user_1.id
  name         = "database_1"
}

1. Опционально: настроить провайдеры⁠

Если вы настроили провайдеры Servercore и OpenStack, пропустите этот шаг.

1. Убедитесь, что в панели управления вы создали сервисного пользователя с ролями Администратор аккаунта и Администратор пользователей.

2. Создайте директорию для хранения конфигурационных файлов и отдельный файл с расширением .tf для настройки провайдеров.

3. В файл для настройки провайдеров добавьте провайдеры Servercore и OpenStack:

   terraform {
     required_providers {
       servercore  = {
         source  = "terraform.servercore.com/servercore/servercore"
         version = "6.0.0"
       }
       openstack = {
         source  = "terraform-provider-openstack/openstack"
         version = "2.1.0"
       }
     }
   }

   Здесь version — версии провайдеров. Актуальную версию провайдера Openstack можно посмотреть в Terraform Registry и GitHub.

   Подробнее о продуктах, услугах и сервисах, которыми можно управлять с помощью провайдеров, в инструкции Провайдеры Servercore и OpenStack.

4. Инициализируйте провайдер Servercore:

   provider "servercore" {
     domain_name = "123456"
     username    = "user"
     password    = "password"
     auth_region = "ru-9"
     auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
   }

   Здесь:

   • domain_name — номер аккаунта Servercore. Можно посмотреть в панели управления в правом верхнем углу;
   • username — имя сервисного пользователя с ролями Администратор аккаунта и Администратор пользователей. Можно посмотреть в панели управления: раздел Управление доступом → Управление пользователями → вкладка Сервисные пользователи (раздел доступен только Владельцу аккаунта и Администратору пользователей);
   • password — пароль сервисного пользователя. Можно посмотреть при создании пользователя или изменить на новый;
   • auth_region — пул, например ru-9. Все ресурсы будут создаваться в этом пуле. Список доступных пулов можно посмотреть в инструкции Матрицы доступности.

5. Создайте проект:

   resource "servercore_project_v2" "project_1" {
     name = "project"
   }

   Посмотрите подробное описание ресурса servercore_vpc_project_v2.

6. Создайте сервисного пользователя для доступа к проекту и назначьте ему роль Администратор проекта:

   resource "servercore_iam_serviceuser_v1" "serviceuser_1" {
     name         = "username"
     password     = "password"
     role {
       role_name  = "member"
       scope      = "project"
       project_id = servercore_project_v2.project_1.id 
     }
   }

   Здесь:

   • username — имя пользователя;
   • password — пароль пользователя. Пароль должен быть не короче восьми символов и содержать латинские буквы разных регистров и цифры;
   • project_id — ID проекта. Можно посмотреть в панели управления: раздел Облачная платформа → откройте меню проектов (название текущего проекта) → в строке нужного проекта нажмите .

   Посмотрите подробное описание ресурса servercore_iam_serviceuser_v1.

7. Инициализируйте провайдер OpenStack:

   provider "openstack" {
     auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
     domain_name = "123456"
     tenant_id   = servercore_project_v2.project_1.id
     user_name   = servercore_iam_serviceuser_v1.serviceuser_1.name
     password    = servercore_iam_serviceuser_v1.serviceuser_1.password
     region      = "ru-9"
   }

   Здесь:

   • domain_name — номер аккаунта Servercore. Можно посмотреть в панели управления в правом верхнем углу;
   • region — пул, например ru-9. Все ресурсы будут создаваться в этом пуле. Список доступных пулов можно посмотреть в инструкции Матрицы доступности.

8. Если одновременно с настройкой провайдеров вы создаете ресурсы, то для ресурсов OpenStack добавьте аргумент depends_on. Например, для ресурса openstack_networking_network_v2:

   resource "openstack_networking_network_v2" "network_1" {
     name           = "private-network"
     admin_state_up = "true"
   
     depends_on = [
       servercore_project_v2.project_1,
       servercore_iam_serviceuser_v1.serviceuser_1
     ]
   }

9. Откройте CLI.

10. Инициализируйте конфигурацию Terraform в директории:

    terraform init

11. Проверьте, что конфигурационные файлы составлены без ошибок:

    terraform validate

12. Отформатируйте конфигурационные файлы:

    terraform fmt

13. Проверьте, какие ресурсы будут созданы:

    terraform plan

14. Примените изменения и создайте ресурсы:

    terraform apply

15. Подтвердите создание — введите yes и нажмите Enter. Созданные ресурсы отобразятся в панели управления.

16. Если для создания ресурсов оказалось недостаточно квот, увеличьте квоты.

2. Создать приватную сеть и подсеть⁠

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

Здесь cidr — CIDR приватной подсети, например 192.168.199.0/24.

Посмотрите подробное описание ресурсов:

• openstack_networking_network_v2;
• openstack_networking_subnet_v2.

3. Создать кластер⁠

Фиксированная конфигурация

data "servercore_dbaas_datastore_type_v1" "datastore_type_1" {
  project_id = servercore_project_v2.project_1.id
  region     = "ru-9"
  filter {
    engine  = "postgresql"
    version = "14-1С"
  }
}

data "servercore_dbaas_flavor_v1" "flavor_1" {
  project_id = servercore_project_v2.project_1.id
  region     = "ru-9"
  filter {
    datastore_type_id = data.servercore_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
    fl_size           = "standard"
    vcpus             = 4
    ram               = 16384
    disk              = 128
    }
  }


resource "servercore_dbaas_postgresql_datastore_v1" "datastore_1" {
  name       = "datastore-1"
  project_id = servercore_project_v2.project_1.id
  region     = "ru-9"
  type_id    = data.servercore_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
  subnet_id  = openstack_networking_subnet_v2.subnet_1.id
  node_count = 3
  flavor_id  = data.servercore_dbaas_flavor_v1.flavor_1.flavors[0].id
  pooler {
    mode = "transaction"
    size = 50
  }
}

Здесь:

• region — пул, например ru-9. Список доступных пулов можно посмотреть в инструкции Матрицы доступности;
• filter — фильтр типов облачных баз данных:
  • engine — тип облачных баз данных. Для кластера PostgreSQL для 1С укажите postgresql;
  • version — версия облачной базы данных в формате <номер версии>-1C, например 14-1C. Список доступных версий можно посмотреть в инструкции Версии и конфигурации;
• filter — фильтр фиксированных конфигураций кластера. Список доступных конфигураций можно посмотреть в инструкции Версии и конфигурации;
  • fl_size — линейка фиксированных конфигураций. Доступные значения — standard (для линеек Standard, CPU и Memory) и high_freq (для линейки HighFreq);
  • vcpus — количество vCPU;
  • ram — количество RAM в МБ;
  • disk — размер диска в ГБ;
• nodes_count — количество нод. Максимальное количество нод — 6.

Посмотрите подробное описание источников данных и ресурсов:

• servercore_dbaas_datastore_type_v1;
• servercore_dbaas_flavor_v1;
• servercore_dbaas_postgresql_datastore_v1.

Произвольная конфигурация

data "servercore_dbaas_datastore_type_v1" "datastore_type_1" {
  project_id = servercore_project_v2.project_1.id
  region     = "ru-9"
  filter {
    engine  = "postgresql"
    version = "14-1С"
  }
}

resource "servercore_dbaas_postgresql_datastore_v1" "datastore_1" {
  name       = "datastore-1"
  project_id = servercore_project_v2.project_1.id
  region     = "ru-9"
  type_id    = data.servercore_dbaas_datastore_type_v1.datastore_type_1.datastore_types[0].id
  subnet_id  = openstack_networking_subnet_v2.subnet_1.id
  node_count = 3
  flavor {
    vcpus = 1
    ram   = 4096
    disk  = 32
  }
}

Здесь:

• region — пул, например ru-9. Список доступных пулов можно посмотреть в инструкции Матрицы доступности;
• filter — фильтр типов облачных баз данных:
  • engine — тип облачных баз данных. Для кластера PostgreSQL для 1С укажите postgresql;
  • version — версия облачной базы данных в формате <номер версии>-1C, например 14-1C. Список доступных версий можно посмотреть в инструкции Версии и конфигурации;
• node_count — количество нод. Максимальное количество нод — 6;
• flavor — произвольная конфигурация кластера. Доступные значения произвольных конфигураций можно посмотреть в инструкции Версии и конфигурации:
  • vcpus — количество vCPU;
  • ram — количество RAM в МБ;
  • disk — размер диска в ГБ.

Посмотрите подробное описание источника данных servercore_dbaas_datastore_type_v1 и ресурса servercore_dbaas_postgresql_datastore_v1.

4. Создать пользователя⁠

resource "servercore_dbaas_user_v1" "user_1" {
  project_id   = servercore_project_v2.project_1.id
  region       = "ru-9"
  datastore_id = servercore_dbaas_postgresql_datastore_v1.datastore_1.id
  name         = "user"
  password     = "secret"
}

Здесь:

• region — пул, в котором находится кластер;
• name — имя пользователя;
• password — пароль пользователя.

Посмотрите подробное описание ресурса servercore_dbaas_user_v1.

5. Создать базу данных и назначить владельца⁠

resource "servercore_dbaas_postgresql_database_v1" "database_1" {
  project_id   = servercore_project_v2.project_1.id
  region       = "ru-9"
  datastore_id = servercore_dbaas_postgresql_datastore_v1.datastore_1.id
  owner_id     = servercore_dbaas_user_v1.user_1.id
  name         = "database_1"
}

Здесь region — пул, в котором находится кластер.

Посмотрите подробное описание ресурса servercore_dbaas_postgresql_database_v1.