Create a cloud server in a private subnet via Terraform

We recommend creating resources in order. If you create all resources at once, Terraform will account for dependencies between resources that you specified in the configuration file. If dependencies are not specified, resources will be created in parallel, which may lead to errors. For instance, a resource required for creating another resource might not have been created yet.

Optional: configure providers.
Add a public SSH key.
Create a private network and subnet.
Create a port for the cloud server.
Get an image.
Create a bootable network volume.
Create a cloud server.

Configuration files

Example file for configuring providers

terraform {
  required_providers {
    servercore  = {
      source  = "terraform.servercore.com/servercore/servercore"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "servercore" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "uz-1"
  auth_url    = "https://cloud.api.servercore.com/identity/v3/"
}

resource "servercore_project_v2" "project_1" {
  name = "project"
}

resource "servercore_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = servercore_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.servercore.com/identity/v3"
  domain_name = "123456"
  tenant_id   = servercore_project_v2.project_1.id
  user_name   = servercore_iam_serviceuser_v1.serviceuser_1.name
  password    = servercore_iam_serviceuser_v1.serviceuser_1.password
  region      = "uz-1"
}

Example file for creating a server in a private subnet

resource "servercore_keypair_v2" "keypair_1" {
  name       = "keypair"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = servercore_iam_serviceuser_v1.serviceuser_1.id
}

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

resource "openstack_networking_port_v2" "port_1" {
  name       = "port"
  network_id = openstack_networking_network_v2.network_1.id

  fixed_ip {
    subnet_id = openstack_networking_subnet_v2.subnet_1.id
  }
}

data "openstack_images_image_v2" "image_1" {
  name        = "Ubuntu 20.04 LTS 64-bit"
  most_recent = true
  visibility  = "public"
}

resource "openstack_blockstorage_volume_v3" "volume_1" {
  name                 = "boot-volume-for-server"
  size                 = "5"
  image_id             = data.openstack_images_image_v2.image_1.id
  volume_type          = "fast.uz-1a"
  availability_zone    = "uz-1a"
  enable_online_resize = true

  lifecycle {
    ignore_changes = [image_id]
  }

}

resource "openstack_compute_instance_v2" "server_1" {
  name              = "server"
  flavor_id         = "4011"
  key_pair          = servercore_keypair_v2.keypair_1.name
  availability_zone = "uz-1a"

  network {
    port = openstack_networking_port_v2.port_1.id
  }

  lifecycle {
    ignore_changes = [image_id]
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_1.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = 0
  }

  vendor_options {
    ignore_resize_confirmation = true
  }
}

1. Optional: configure providers

If you have configured the Servercore and OpenStack providers, skip this step.

Make sure you have created a service user in the control panel member with roles in the Account access scope and iam.admin.
Create a directory to store configuration files and a separate file with the .tf extension to configure providers.
Add the Servercore and OpenStack providers to the file for provider configuration:
```
terraform {
  required_providers {
    servercore  = {
      source  = "terraform.servercore.com/servercore/servercore"
      version = "~> 7.1.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}
```
Here version is the provider version. The current version of the OpenStack provider can be found in the Terraform Registry and GitHub.

For more information about products, services, and features that can be managed using providers, see the Servercore and OpenStack Providers guide.
Initialize the Servercore provider:
```
provider "servercore" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "uz-1"
  auth_url    = "https://cloud.api.servercore.com/identity/v3/"
}
```
Where:
- domain_name — Servercore account number. You can find it in the control panel in the top-right corner;
- username — the name of the service user with the member role in the Account access scope and iam.admin. You can view it in the control panel: in the top menu, click IAM → Service Users section (this section is only available to the account owner and users with the iam.admin role);
- password — service user password. You can view it when creating the user or change it to a new one;
- auth_region — pool for authorization in the uz-1 format; do not use pools in the SPB-2 format. The authorization pool might not match the pool in which you create resources. The list of available pools can be viewed in the guide Product availability by location.
Create a project:
```
resource "servercore_project_v2" "project_1" {
  name = "project"
}
```
See the detailed resource description for servercore_project_v2.
Create a service user for project access and assign the member role in the Project access scope:
```
resource "servercore_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = servercore_project_v2.project_1.id
  }
}
```
Where:
- username — user name;
- password — user password. The password must be at least 20 characters long and include at least:
  - one uppercase and one lowercase Latin letter (A-Z, a-z);
  - one digit (0-9);
  - one special character from the ASCII Printable 7-Bit Special Characters list:
    !"#$%&'()*+,-./:;<=>?@[]^_{|}~;
- project_id — project ID. You can find it in the Control panel: in the top menu, click IAM → the Projects section → in the line of the required project, click .
View the detailed description of the resource servercore_iam_serviceuser_v1.

Initialize the OpenStack provider:

provider "openstack" {
  auth_url    = "https://cloud.api.servercore.com/identity/v3"
  domain_name = "123456"
  tenant_id   = servercore_project_v2.project_1.id
  user_name   = servercore_iam_serviceuser_v1.serviceuser_1.name
  password    = servercore_iam_serviceuser_v1.serviceuser_1.password
  region      = "uz-1"
}

Where:

domain_name — Servercore account number. You can find it in the Control panel in the upper right corner;
region — pool, for example uz-1. All resources will be created in this pool. The list of available pools can be viewed in the guide Product availability by location.

If you create resources at the same time as configuring providers, add the depends_on argument for OpenStack resources. For example, for the openstack_networking_network_v2 resource:

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"

  depends_on = [
    servercore_project_v2.project_1,
    servercore_iam_serviceuser_v1.serviceuser_1
  ]
}

Open the CLI.
Initialize the Terraform configuration in the directory:
```
terraform init
```
Verify that the configuration files are syntactically correct:
```
terraform validate
```
Format the configuration files:
```
terraform fmt
```
Check which resources will be created:
```
terraform plan
```
Apply the changes and create the resources:
```
terraform apply
```
Confirm the creation: enter yes and press Enter. The created resources will be displayed in the Control panel.
If there are not enough quotas to create resources, increase quotas.

2. Add a public SSH key

resource "servercore_keypair_v2" "keypair_1" {
  name       = "keypair"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = servercore_iam_serviceuser_v1.serviceuser_1.id
}

Here public_key is the path to the public SSH key. If SSH keys are not generated, create them.

See the detailed description of the servercore_keypair_v2 resource.

3. Create a private network and subnet

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

Here cidr is the private subnet CIDR, for example 192.168.199.0/24.

See the detailed resource description:

4. Create a port for the cloud server

resource "openstack_networking_port_v2" "port_1" {
  name       = "port"
  network_id = openstack_networking_network_v2.network_1.id

  fixed_ip {
    subnet_id = openstack_networking_subnet_v2.subnet_1.id
  }
}

See the detailed description of the openstack_networking_port_v2 resource.

5. Get an image

data "openstack_images_image_v2" "image_1" {
  name        = "Ubuntu 20.04 LTS 64-bit"
  most_recent = true
  visibility  = "public"
}

See the detailed description of the openstack_images_image_v2 data source.

6. Create a bootable network volume

resource "openstack_blockstorage_volume_v3" "volume_1" {
  name                 = "boot-volume-for-server"
  size                 = "5"
  image_id             = data.openstack_images_image_v2.image_1.id
  volume_type          = "fast.uz-1a"
  availability_zone    = "uz-1a"
  enable_online_resize = true

  lifecycle {
    ignore_changes = [image_id]
  }

}

Here:

size — network volume size in GB. Observe the network volume limits for the maximum size;
volume_type — ID or name of the network volume type. For example, fast.uz-1a — name to create a network volume with the Fast SSD type in the pool segment uz-1a. You can check the list of types in the table List of network volume types in all pool segments;
availability_zone — pool segment where the network volume will be created, for example, uz-1a. You can check the list of available pool segments in the instructions Product availability by location.

See the detailed resource description in openstack_blockstorage_volume_v3.

7. Create a cloud server

resource "openstack_compute_instance_v2" "server_1" {
  name              = "server"
  flavor_id         = "1015"
  key_pair          = servercore_keypair_v2.keypair_1.name
  availability_zone = "uz-1a"

  network {
    port = openstack_networking_port_v2.port_1.id
  }

  lifecycle {
    ignore_changes = [image_id]
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_1.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = 0
  }

  vendor_options {
    ignore_resize_confirmation = true
  }
}

Where:

availability_zone — pool segment in which the cloud server will be created, for example uz-1a. The list of available pool segments can be found in the instructions on Product availability by location;
flavor_id — flavor ID. Flavors correspond to cloud server configurations and define the number of vCPUs, RAM, and the size of the local disk (optional) for the server. You can use fixed-configuration flavors. For example, 1015 is the ID for creating a server with a Standard line fixed configuration with 4 vCPUs and 16 GB of RAM in the uz-1 pool. A list of flavors is available in the table List of fixed-configuration flavors in all pools.

See the detailed description of the openstack_compute_instance_v2 resource.