Create a network volume using Terraform

We recommend creating resources in order. If you create all resources at once, Terraform will account for dependencies between resources that you specified in the configuration file. If dependencies are not specified, resources will be created in parallel, which may lead to errors. For instance, a resource required for creating another resource might not have been created yet.

1. Optional: configure providers.

2. Create a network volume.

   For all network volume types, except for the Universal v2 type, the number of IOPS is fixed and depends on the volume type. For Universal v2 network volumes, you can increase or decrease the total volume IOPS. The number of IOPS changes is unlimited. Available IOPS values for different volume types can be viewed in the Network volume limits subsection.

   You can create a volume:

   • from an image — can be used as a cloud server boot volume;
   • or empty — can be used as an additional volume.

Configuration files

Example of a file for configuring providers

terraform {
  required_providers {
    servercore  = {
      source  = "terraform.servercore.com/servercore/servercore"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "servercore" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "uz-1"
  auth_url    = "https://cloud.api.servercore.com/identity/v3/"
}

resource "servercore_project_v2" "project_1" {
  name = "project"
}

resource "servercore_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = servercore_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.servercore.com/identity/v3"
  domain_name = "123456"
  tenant_id   = servercore_project_v2.project_1.id
  user_name   = servercore_iam_serviceuser_v1.serviceuser_1.name
  password    = servercore_iam_serviceuser_v1.serviceuser_1.password
  region      = "uz-1"
}

Example of a file for creating a network volume from an image

data "openstack_images_image_v2" "image_1" {
  name        = "Ubuntu 20.04 LTS 64-bit"
  most_recent = true
  visibility  = "public"
}

resource "openstack_blockstorage_volume_v3" "volume_1" {
  name                 = "boot-volume-for-server"
  size                 = "5"
  image_id             = data.openstack_images_image_v2.image_1.id
  volume_type          = "fast.uz-1a"
  availability_zone    = "uz-1a"
  enable_online_resize = true

  lifecycle {
    ignore_changes = [image_id]
  }

}

Example of a file for creating an empty network volume

resource "openstack_blockstorage_volume_v3" "volume_2" {
  name                 = "additional-volume-for-server"
  size                 = "7"
  volume_type          = "universal.uz-1a"
  availability_zone    = "uz-1a"
  enable_online_resize = true
}

1. Optional: configure providers

If you have configured the Servercore and OpenStack providers, skip this step.

1. Make sure that in the control panel you have created a service user with the member role in the Account access scope and iam.admin.

2. Create a directory to store configuration files and a separate file with the .tf extension to configure providers.

3. Add the Servercore and OpenStack providers to the file for provider configuration:

   terraform {
     required_providers {
       servercore  = {
         source  = "terraform.servercore.com/servercore/servercore"
         version = "~> 7.1.0"
       }
       openstack = {
         source  = "terraform-provider-openstack/openstack"
         version = "2.1.0"
       }
     }
   }

   Here version is the provider version. The current version of the OpenStack provider can be found in the Terraform Registry and GitHub.

   For more information about products, services, and features that can be managed using providers, see the Servercore and OpenStack Providers guide.

4. Initialize the Servercore provider:

   provider "servercore" {
     domain_name = "123456"
     username    = "user"
     password    = "password"
     auth_region = "uz-1"
     auth_url    = "https://cloud.api.servercore.com/identity/v3/"
   }

   Where:

   • domain_name — Servercore account number. You can find it in the control panel in the top-right corner;
   • username — name of the service user with the member role in the Account access scope and iam.admin. You can view it in the control panel: in the top menu, click IAM → Service Users section (the section is only available to the Account Owner and a user with the iam.admin role);
   • password — service user password. You can view it when creating the user or change it to a new one;
   • auth_region — pool for authorization, for example, uz-1. You can create resources in other pools. A list of available pools can be found in the Availability Matrix guide.

5. Create a project:

   resource "servercore_project_v2" "project_1" {
     name = "project"
   }

   See a detailed description of the servercore_project_v2 resource.

6. Create a service user to access the project and assign them the member role in the Project access scope:

   resource "servercore_iam_serviceuser_v1" "serviceuser_1" {
     name         = "username"
     password     = "password"
     role {
       role_name  = "member"
       scope      = "project"
       project_id = servercore_project_v2.project_1.id
     }
   }

   Where:

   • username — username;

   • password — user password. The password must be at least 20 characters long and include at least:

     • one uppercase and one lowercase Latin letter (A-Z, a-z);
     • one digit (0-9);
     • one special character from the ASCII Printable 7-Bit Special Characters list:
       !"#$%&'()*+,-./:;<=>?@[]^_{|}~;

   • project_id — project ID. You can find it in the control panel: in the top menu, click Products and select Cloud Servers → open the projects menu → in the row of the target project, click .

   See a detailed description of the servercore_iam_serviceuser_v1 resource.

7. Initialize the OpenStack provider:

   provider "openstack" {
     auth_url    = "https://cloud.api.servercore.com/identity/v3"
     domain_name = "123456"
     tenant_id   = servercore_project_v2.project_1.id
     user_name   = servercore_iam_serviceuser_v1.serviceuser_1.name
     password    = servercore_iam_serviceuser_v1.serviceuser_1.password
     region      = "uz-1"
   }

   Where:

   • domain_name — Servercore account number. You can find it in the control panel in the top-right corner;
   • region — pool, for example, uz-1. All resources will be created in this pool. A list of available pools can be found in the Availability Matrix guide.

8. If you are creating resources while configuring providers, add the depends_on argument for OpenStack resources. For example, for the openstack_networking_network_v2 resource:

   resource "openstack_networking_network_v2" "network_1" {
     name           = "private-network"
     admin_state_up = "true"
   
     depends_on = [
       servercore_project_v2.project_1,
       servercore_iam_serviceuser_v1.serviceuser_1
     ]
   }

9. Open the CLI.

10. Initialize the Terraform configuration in the directory:

    terraform init

11. Verify that the configuration files are syntactically correct:

    terraform validate

12. Format the configuration files:

    terraform fmt

13. Check which resources will be created:

    terraform plan

14. Apply the changes and create the resources:

    terraform apply

15. Confirm creation — enter yes and press Enter. The created resources will appear in the control panel.

16. If quotas were insufficient to create the resources, increase the quotas.

2. Create a network volume

Network volume with fixed IOPS

For all network volume types, except for the Universal v2 type, the number of IOPS is fixed and depends on the volume type. Available IOPS values for different volume types can be viewed in the Network volume limits subsection.

Network volume from an image

1. Get an image.
2. Create a network volume.

1. Get an image

data "openstack_images_image_v2" "image_1" {
  name        = "Ubuntu 20.04 LTS 64-bit"
  most_recent = true
  visibility  = "public"
}

See the detailed description of the openstack_images_image_v2 data source.

2. Create a network volume from an image

resource "openstack_blockstorage_volume_v3" "volume_1" {
  name                 = "boot-volume-for-server"
  size                 = "5"
  image_id             = data.openstack_images_image_v2.image_1.id
  volume_type          = "fast.uz-1a"
  availability_zone    = "uz-1a"
  enable_online_resize = true

  lifecycle {
    ignore_changes = [image_id]
  }

}

Here:

• size — network volume size in GB. Observe the network volume limits for the maximum size;
• volume_type — ID or name of the network volume type. For example, fast.uz-1a — name for creating a network volume with the Fast SSD type in the pool segment uz-1a. The list of types can be viewed in the table List of network volume types in all pool segments;
• availability_zone — pool segment, in which the network volume will be created, for example, uz-1a. The list of available pool segments can be viewed in the Availability Matrix.

See the detailed resource description in openstack_blockstorage_volume_v3.

Empty network volume

resource "openstack_blockstorage_volume_v3" "volume_2" {
  name                 = "additional-volume-for-server"
  size                 = "7"
  volume_type          = "universal.uz-1a"
  availability_zone    = "uz-1a"
  enable_online_resize = true
}

Where:

• size — network volume size in GB. Observe the network volume limits for the maximum size;
• volume_type — ID or name of the network volume type. For example, universal.uz-1a — name to create a network volume with the SSD Universal type in the pool segment uz-1a. A list of types can be viewed in the table List of network volume types in all pool segments;
• availability_zone — pool segment, in which the network volume will be created, e.g. uz-1a. A list of available pool segments can be checked in the Availability Matrix.

See the detailed resource description openstack_blockstorage_volume_v3.

Network volume with scalable IOPS

For Universal v2 network volumes, you can change the total IOPS — increase or decrease. Available values are from 2 000 to 16 000 IOPS. The number of IOPS changes is unlimited.

Network volume from an image

1. Get an image.
2. Create a network volume.

1. Get an image

data "openstack_images_image_v2" "image_1" {
  name        = "Ubuntu 20.04 LTS 64-bit"
  most_recent = true
  visibility  = "public"
}

See the detailed description of the openstack_images_image_v2 data source.

2. Create a network volume from an image

resource "openstack_blockstorage_volume_v3" "volume_1" {
  name                 = "boot-volume-for-server"
  size                 = "5"
  image_id             = data.openstack_images_image_v2.image_1.id
  volume_type          = "universal2.uz-1a"
  availability_zone    = "uz-1a"
  enable_online_resize = true
  metadata             = {"total_iops_sec": "4500"}

  lifecycle {
    ignore_changes = [image_id]
  }

}

Where:

• size — volume size in GB. Consider the network volume limits for the maximum size;

• volume_type — ID or name of the network volume type. For example, universal2.uz-1a — the name for creating a network volume of the SSD Universal v2 type in the pool segment uz-1a. A list of types can be viewed in the table List of network volume types in all pool segments;

• availability_zone — the pool segment in which the network volume will be created, for example, uz-1a. A list of available pool segments can be viewed in the Availability Matrix guide;

• metadata — key/value pairs for storing additional information about the volume:

  • total_iops_sec — total number of read and write operations in IOPS. Available values are from 2 000 to 16 000 IOPS. If you do not specify a value, the default value of 2 000 IOPS will be used.

See the detailed resource description in openstack_blockstorage_volume_v3.

Empty network volume

resource "openstack_blockstorage_volume_v3" "volume_3" {
  name                 = "volume-with-custom-iops"
  size                 = "7"
  volume_type          = "universal2.uz-1a"
  availability_zone    = "uz-1a"
  enable_online_resize = true
  metadata             = {"total_iops_sec": "4500"}
}

Where:

• size — volume size in GB. Consider the network volume limits for the maximum size;

• volume_type — ID or name of the Universal v2 network volume type. For example, universal2.uz-1a — the name for creating a network volume of the SSD Universal v2 type in the pool segment uz-1a. A list of types can be viewed in the table List of network volume types in all pool segments;

• availability_zone — the pool segment where the network volume will be created, e.g. uz-1a. For a list of available pool segments, see the Availability Matrix guide;

• metadata — key/value pairs for storing additional information about the volume:

  • total_iops_sec — total number of read and write operations in IOPS. Available values are from 2 000 to 16 000 IOPS. If you do not specify a value, the default value of 2 000 IOPS will be used.

See the detailed resource description in openstack_blockstorage_volume_v3.