Create a fixed configuration cloud server with dedicated cores and a bootable network volume via Terraform

We recommend creating resources in order. If you create all resources at once, Terraform will account for dependencies between resources that you specified in the configuration file. If dependencies are not specified, resources will be created in parallel, which may lead to errors. For instance, a resource required for creating another resource might not have been created yet.

1. Optional: configure providers.

2. Add a public SSH key.

3. Create a private network and a subnet.

4. Create a cloud router connected to the internet.

5. Create a port for the cloud server.

6. Get an image.

7. Create a bootable network volume.

8. Create a cloud server.

9. Create a public IP address.

10. Associate the cloud server’s public and private IP addresses.

11. Get the cloud server IP address.

Configuration files

Example file for configuring providers

terraform {
  required_providers {
    servercore  = {
      source  = "terraform.servercore.com/servercore/servercore"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "servercore" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-7"
  auth_url    = "https://cloud.api.servercore.com/identity/v3/"
}

resource "servercore_project_v2" "project_1" {
  name = "project"
}

resource "servercore_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = servercore_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.servercore.com/identity/v3"
  domain_name = "123456"
  tenant_id   = servercore_project_v2.project_1.id
  user_name   = servercore_iam_serviceuser_v1.serviceuser_1.name
  password    = servercore_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-7"
}

Example file for creating a server with dedicated cores

resource "servercore_keypair_v2" "keypair_1" {
    name       = "keypair"
    public_key = file("~/.ssh/id_rsa.pub")
    user_id    = servercore_iam_serviceuser_v1.serviceuser_1.id
}

resource "openstack_networking_network_v2" "network_1" {
    name           = "private-network"
    admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
    network_id = openstack_networking_network_v2.network_1.id
    cidr       = "192.168.199.0/24"
}

data "openstack_networking_network_v2" "external_network_1" {
    external = true
}

resource "openstack_networking_router_v2" "router_1" {
    name                = "router"
    external_network_id = data.openstack_networking_network_v2.external_network_1.id
}

resource "openstack_networking_router_interface_v2" "router_interface_1" {
    router_id = openstack_networking_router_v2.router_1.id
    subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

resource "openstack_networking_port_v2" "port_1" {
    name       = "port"
    network_id = openstack_networking_network_v2.network_1.id

    fixed_ip {
      subnet_id = openstack_networking_subnet_v2.subnet_1.id
    }
}

data "openstack_images_image_v2" "image_1" {
    name        = "Ubuntu 20.04 LTS 64-bit"
    most_recent = true
    visibility  = "public"
}

resource "openstack_blockstorage_volume_v3" "volume_1" {
    name                 = "boot-volume-for-server"
    size                 = "5"
    image_id             = data.openstack_images_image_v2.image_1.id
    volume_type          = "fast.ru-7b"
    availability_zone    = "ru-7b"
    enable_online_resize = true

    lifecycle {
      ignore_changes = [image_id]
    }

}

resource "openstack_compute_instance_v2" "server_1" {
  name              = "server"
  flavor_id         = "1063"
  key_pair          = servercore_keypair_v2.keypair_1.name
  availability_zone = "ru-7b"

  network {
    port = openstack_networking_port_v2.port_1.id
  }

  lifecycle {
    ignore_changes = [image_id]
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_1.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = 0
  }

  vendor_options {
    ignore_resize_confirmation = true
  }
}

resource "openstack_networking_floatingip_v2" "floatingip_1" {
    pool = "external-network"
}

resource "openstack_networking_floatingip_associate_v2" "association_1" {
    port_id     = openstack_networking_port_v2.port_1.id
    floating_ip = openstack_networking_floatingip_v2.floatingip_1.address
}

output "public_ip_address" {
    value = openstack_networking_floatingip_v2.floatingip_1.fixed_ip
}

1. Optional: configure providers

If you have already configured Servercore and OpenStack providers, skip this step.

1. Ensure that you have created a service user with the member role in the Account access scope and the iam.admin role.

2. Create a directory to store configuration files and a separate file with the .tf extension for configuring providers.

3. Add the Servercore and OpenStack providers to the provider configuration file:

   terraform {
     required_providers {
       servercore  = {
         source  = "terraform.servercore.com/servercore/servercore"
         version = "~> 6.0"
       }
       openstack = {
         source  = "terraform-provider-openstack/openstack"
         version = "2.1.0"
       }
     }
   }

   Where version is the provider version. The current OpenStack provider version can be found in Terraform Registry and GitHub.

   For more information about products, services, and features that can be managed using providers, see the Servercore and OpenStack Providers guide.

4. Initialize the Servercore provider:

   provider "servercore" {
     domain_name = "123456"
     username    = "user"
     password    = "password"
     auth_region = "ru-7"
     auth_url    = "https://cloud.api.servercore.com/identity/v3/"
   }

   Where:

   • domain_name — Servercore account ID. It can be found in the control panel in the top-right corner;
   • username — the name of the service user with the member role in the Account access scope and the iam.admin role. You can view it in the control panel: in the top menu, click IAM → Service users section (available only to the account owner and users with the iam.admin role);
   • password — service user password. You can view it when creating the user or change it to a new one;
   • auth_region — pool for authorization in the format ru-7; do not use pools in the format SPB-2. The authorization pool might not match the pool where you create resources. You can view the list of available pools in the Product Availability by Location.

5. Create a project:

   resource "servercore_project_v2" "project_1" {
     name = "project"
   }

   See the detailed description of the servercore_project_v2 resource.

6. Create a service user for project access and assign them the member role in the Project access scope:

   resource "servercore_iam_serviceuser_v1" "serviceuser_1" {
     name         = "username"
     password     = "password"
     role {
       role_name  = "member"
       scope      = "project"
       project_id = servercore_project_v2.project_1.id
     }
   }

   Where:

   • username — user name;
   • password — user password. The password must be at least eight characters long and contain uppercase and lowercase Latin letters and digits;
   • project_id — project ID. You can view it in the control panel: from the top menu, click Products and select Cloud Servers → open the project menu → in the row with the desired project, click .

   See the detailed description of the resource servercore_iam_serviceuser_v1.

7. Initialize the OpenStack provider:

   provider "openstack" {
     auth_url    = "https://cloud.api.servercore.com/identity/v3"
     domain_name = "123456"
     tenant_id   = servercore_project_v2.project_1.id
     user_name   = servercore_iam_serviceuser_v1.serviceuser_1.name
     password    = servercore_iam_serviceuser_v1.serviceuser_1.password
     region      = "ru-7"
   }

   Where:

   • domain_name — Servercore account number. You can view it in the control panel in the upper-right corner;
   • region — pool, for example ru-7. All resources will be created in this pool. You can view the list of available pools in the Product Availability by Location.

8. If you create resources while configuring providers, add the depends_on argument for OpenStack resources. For example, for the openstack_networking_network_v2 resource:

   resource "openstack_networking_network_v2" "network_1" {
     name           = "private-network"
     admin_state_up = "true"
   
     depends_on = [
       servercore_project_v2.project_1,
       servercore_iam_serviceuser_v1.serviceuser_1
     ]
   }

9. Open the CLI.

10. Initialize the Terraform configuration in the directory:

    terraform init

11. Verify that the configuration files are syntactically correct:

    terraform validate

12. Format the configuration files:

    terraform fmt

13. Check which resources will be created:

    terraform plan

14. Apply the changes and create the resources:

    terraform apply

15. Confirm creation — enter yes and press Enter. The created resources will appear in the control panel.

16. If there are not enough quotas to create resources, increase quotas.

2. Create an SSH key pair

resource "servercore_keypair_v2" "keypair_1" {
  name       = "keypair"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = servercore_iam_serviceuser_v1.serviceuser_1.id
}

Here public_key is the path to the public SSH key. If SSH keys are not generated, create them.

See the detailed description of the servercore_keypair_v2 resource.

3. Create a private network and a subnet

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

Here cidr is the private subnet CIDR, for example 192.168.199.0/24.

See the detailed resource description:

• openstack_networking_network_v2;
• openstack_networking_subnet_v2.

4. Create a cloud router connected to the internet

A cloud router connected to the internet performs 1:1 NAT for traffic from a private network to the internet via the router's public IP address.

data "openstack_networking_network_v2" "external_network_1" {
  external = true
}

resource "openstack_networking_router_v2" "router_1" {
  name                = "router"
  external_network_id = data.openstack_networking_network_v2.external_network_1.id
}

resource "openstack_networking_router_interface_v2" "router_interface_1" {
  router_id = openstack_networking_router_v2.router_1.id
  subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

See the detailed resource description:

• openstack_networking_network_v2;
• openstack_networking_router_v2;
• openstack_networking_router_interface_v2.

5. Create a port for the cloud server

resource "openstack_networking_port_v2" "port_1" {
  name       = "port"
  network_id = openstack_networking_network_v2.network_1.id

  fixed_ip {
    subnet_id = openstack_networking_subnet_v2.subnet_1.id
  }
}

See the detailed description of the openstack_networking_port_v2 resource.

6. Get an image

data "openstack_images_image_v2" "image_1" {
  name        = "Ubuntu 20.04 LTS 64-bit"
  most_recent = true
  visibility  = "public"
}

See the detailed description of the openstack_images_image_v2 data source.

7. Create a bootable network volume

resource "openstack_blockstorage_volume_v3" "volume_1" {
    name                 = "boot-volume-for-server"
    size                 = "5"
    image_id             = data.openstack_images_image_v2.image_1.id
    volume_type          = "fast.ru-7b"
    availability_zone    = "ru-7b"
    enable_online_resize = true

    lifecycle {
      ignore_changes = [image_id]
    }

}

8. Create a cloud server

resource "openstack_compute_instance_v2" "server_1" {
  name              = "server"
  flavor_id         = "1063"
  key_pair          = servercore_keypair_v2.keypair_1.name
  availability_zone = "ru-7b"

  network {
    port = openstack_networking_port_v2.port_1.id
  }

  lifecycle {
    ignore_changes = [image_id]
  }

  block_device {
    uuid             = openstack_blockstorage_volume_v3.volume_1.id
    source_type      = "volume"
    destination_type = "volume"
    boot_index       = 0
  }

  vendor_options {
    ignore_resize_confirmation = true
  }
}

Where:

• availability_zone — pool segment where the cloud server will be created, for example ru-7b. Cloud servers with dedicated cores are available only in the ru-3b, ru-7a, and ru-7b pool segments.
• flavor_id — ID of the flavor with dedicated cores. Flavors correspond to cloud server configurations and determine the number of vCPUs, RAM, and local disk size. For example, 1063 is a fixed configuration flavor of the Standard line with 12 vCPUs and 48 GB RAM for creating a cloud server with dedicated cores. Flavors supporting dedicated cores are available in the Standard and HighFreq lines. You can view the list of available flavors in the List of fixed configuration flavors across all pools section of the Cloud Server Configurations instructions.

See the detailed description of the resource openstack_compute_instance_v2.

9. Create a public IP address

resource "openstack_networking_floatingip_v2" "floatingip_1" {
  pool = "external-network"
}

See the detailed description of the openstack_networking_floatingip_v2 resource.

10. Associate the cloud server’s public and private IP addresses

The public IP address will be connected to the cloud server port and associated with the private IP.

resource "openstack_networking_floatingip_associate_v2" "association_1" {
  port_id     = openstack_networking_port_v2.port_1.id
  floating_ip = openstack_networking_floatingip_v2.floatingip_1.address
}

See the detailed description of the openstack_networking_floatingip_associate_v2 resource.

11. Get the cloud server’s IP address

output "public_ip_address" {
  value = openstack_networking_floatingip_v2.floatingip_1.fixed_ip
}