Create HDD Basic file storage via Terraform

We recommend creating resources in order. If you create all resources at once, Terraform will account for dependencies between resources that you specified in the configuration file. If dependencies are not specified, resources will be created in parallel, which may lead to errors. For instance, a resource required for creating another resource might not have been created yet.

Optional: configure providers.
Create a private network and subnet.
Configure the storage network.
Create a file storage.
Configure file storage access rules.

Configuration files

Example file for provider configuration

terraform {
  required_providers {
    servercore  = {
      source  = "terraform.servercore.com/servercore/servercore"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "servercore" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "uz-1"
  auth_url    = "https://cloud.api.servercore.com/identity/v3/"
}

resource "servercore_project_v2" "project_1" {
  name = "project"
}

resource "servercore_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = servercore_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.servercore.com/identity/v3"
  domain_name = "123456"
  tenant_id   = servercore_project_v2.project_1.id
  user_name   = servercore_iam_serviceuser_v1.serviceuser_1.name
  password    = servercore_iam_serviceuser_v1.serviceuser_1.password
  region      = "uz-1"
}

Example file for creating file storage

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

resource "openstack_sharedfilesystem_sharenetwork_v2" "sharenetwork_1" {
  name              = "share-network"
  neutron_net_id    = openstack_networking_network_v2.network_1.id
  neutron_subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

resource "openstack_sharedfilesystem_share_v2" "share_1" {
  name             = "nfs-storage"
  share_type       = "basic.uz-1a"
  share_proto      = "NFS"
  size             = 50
  share_network_id = openstack_sharedfilesystem_sharenetwork_v2.sharenetwork_1.id
  metadata         = {"ip": "192.168.199.3"}
}

resource "openstack_sharedfilesystem_share_access_v2" "shareaccess_1" {
  access_level = "rw"
  access_to    = "0.0.0.0/0"
  access_type  = "ip"
  share_id     = openstack_sharedfilesystem_share_v2.share_1.id
}

1. Optional: configure providers

If you have configured the Servercore and OpenStack providers, skip this step.

Make sure you have created a service user in the control panel member with roles in the Account access scope and iam.admin.
Create a directory to store configuration files and a separate file with the .tf extension to configure providers.
Add the Servercore and OpenStack providers to the file for provider configuration:
```
terraform {
  required_providers {
    servercore  = {
      source  = "terraform.servercore.com/servercore/servercore"
      version = "~> 7.1.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}
```
Here version is the provider version. The current version of the OpenStack provider can be found in the Terraform Registry and GitHub.

For more information about products, services, and features that can be managed using providers, see the Servercore and OpenStack Providers guide.
Initialize the Servercore provider:
```
provider "servercore" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "uz-1"
  auth_url    = "https://cloud.api.servercore.com/identity/v3/"
}
```
Where:
- domain_name — Servercore account number. You can find it in the control panel in the top-right corner;
- username — the name of the service user with the member role in the Account access scope and iam.admin. You can view it in the control panel: in the top menu, click IAM → Service Users section (this section is only available to the account owner and users with the iam.admin role);
- password — service user password. You can view it when creating the user or change it to a new one;
- auth_region — pool for authorization in the uz-1 format; do not use pools in the SPB-2 format. The authorization pool might not match the pool in which you create resources. The list of available pools can be viewed in the guide Product availability by location.
Create a project:
```
resource "servercore_project_v2" "project_1" {
  name = "project"
}
```
See the detailed resource description for servercore_project_v2.
Create a service user for project access and assign the member role in the Project access scope:
```
resource "servercore_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = servercore_project_v2.project_1.id
  }
}
```
Where:
- username — user name;
- password — user password. The password must be at least 20 characters long and include at least:
  - one uppercase and one lowercase Latin letter (A-Z, a-z);
  - one digit (0-9);
  - one special character from the ASCII Printable 7-Bit Special Characters list:
    !"#$%&'()*+,-./:;<=>?@[]^_{|}~;
- project_id — project ID. You can find it in the Control panel: in the top menu, click IAM → the Projects section → in the line of the required project, click .
View the detailed description of the resource servercore_iam_serviceuser_v1.

Initialize the OpenStack provider:

provider "openstack" {
  auth_url    = "https://cloud.api.servercore.com/identity/v3"
  domain_name = "123456"
  tenant_id   = servercore_project_v2.project_1.id
  user_name   = servercore_iam_serviceuser_v1.serviceuser_1.name
  password    = servercore_iam_serviceuser_v1.serviceuser_1.password
  region      = "uz-1"
}

Where:

domain_name — Servercore account number. You can find it in the Control panel in the upper right corner;
region — pool, for example uz-1. All resources will be created in this pool. The list of available pools can be viewed in the guide Product availability by location.

If you create resources at the same time as configuring providers, add the depends_on argument for OpenStack resources. For example, for the openstack_networking_network_v2 resource:

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"

  depends_on = [
    servercore_project_v2.project_1,
    servercore_iam_serviceuser_v1.serviceuser_1
  ]
}

Open the CLI.
Initialize the Terraform configuration in the directory:
```
terraform init
```
Verify that the configuration files are syntactically correct:
```
terraform validate
```
Format the configuration files:
```
terraform fmt
```
Check which resources will be created:
```
terraform plan
```
Apply the changes and create the resources:
```
terraform apply
```
Confirm the creation: enter yes and press Enter. The created resources will be displayed in the Control panel.
If there are not enough quotas to create resources, increase quotas.

2. Create a private network and subnet

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

Here cidr is the private subnet CIDR, for example 192.168.199.0/24.

See the detailed resource description:

3. Configure the storage network

resource "openstack_sharedfilesystem_sharenetwork_v2" "sharenetwork_1" {
  name              = "share-network"
  neutron_net_id    = openstack_networking_network_v2.network_1.id
  neutron_subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

See the detailed resource description openstack_sharedfilesystem_sharenetwork_v2.

4. Create a file storage

resource "openstack_sharedfilesystem_share_v2" "share_1" {
  name             = "nfs-storage"
  share_type       = "basic.uz-1a"
  share_proto      = "NFS"
  size             = 50
  share_network_id = openstack_sharedfilesystem_sharenetwork_v2.sharenetwork_1.id
  metadata         = {"ip": "192.168.199.3"}
}

Where:

share_type — file storage type and pool segment in the format <type>.<pool_segment>, e.g. basic.uz-1a:
- <type>:
  - basic — HDD Basic type;
  - universal — SSD Universal type;
  - fast — SSD Fast type;
- <pool_segment> — pool segment where the file storage will be created, for example, uz-1a. For a list of available pool segments, see the instructions on Product availability by location;
share_proto — file storage protocol: NFS or CIFS;
size — file storage size in GB, e.g. 50. Limitations — from 50 GB to 50 TB;
optional: metadata = {"ip": "<ip_address>"} — private IP address of the file storage, e.g. 192.168.0.3. After the storage is created, the IP address cannot be changed.

See the detailed resource description openstack_sharedfilesystem_share_v2.

5. Configure file storage access rules

resource "openstack_sharedfilesystem_share_access_v2" "shareaccess_1" {
  access_level = "rw"
  access_to    = "0.0.0.0/0"
  access_type  = "ip"
  share_id     = openstack_sharedfilesystem_share_v2.share_1.id
}

Where:

access_level — access level to the storage, depends on the protocol:
- for CIFS SMBv3 — rw (read and write);
- for NFSv4 — ro (read-only) or rw (read and write);
access_to — IP address or CIDR of the private subnet to which access will be granted. For example:
- 192.168.199.10 — access for an IP address;
- 192.168.199.0/24 — access for a private subnet range;
- 0.0.0.0/0 — access for all private subnet addresses. To configure this access, you can add the openstack_sharedfilesystem_share_v2 resource line metadata = {"access_list_allow_all": "true"}.

See the detailed resource description openstack_sharedfilesystem_share_access_v2.