Create multiple identical cloud servers on the same private network

We recommend that you create resources in order. If you create all resources at once, Terraform will take into account the dependencies between resources that you specify in the configuration file. If dependencies are not specified, resources will be created in parallel, which can cause errors. For example, a resource that is required to create another resource may not have been created yet.

Optional: configure the providers.
Add a public SSH key.
Create a private network and subnet.
Create a cloud router connected to an external network.
Create ports for cloud servers.
Get an image.
Create cloud servers.
Create public IP addresses.
Associate public and private IP addresses of cloud servers.

Configuration files⁠

Example file for configuring providers

terraform {
  required_providers {
    servercore  = {
      source  = "terraform.servercore.com/servercore/servercore"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}

provider "servercore" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-9"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}

resource "servercore_project_v2" "project_1" {
  name = "project"
}

resource "servercore_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = servercore_project_v2.project_1.id 
  }
}

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = servercore_project_v2.project_1.id
  user_name   = servercore_iam_serviceuser_v1.serviceuser_1.name
  password    = servercore_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Sample file for creating servers

    resource "servercore_keypair_v2" "keypair_1" {
        name       = "keypair"
        public_key = file("~/.ssh/id_rsa.pub")
        user_id    = servercore_iam_serviceuser_v1.serviceuser_1.id
    }

    resource "openstack_networking_network_v2" "network_1" {
        name           = "private-network"
        admin_state_up = "true"
    }

    resource "openstack_networking_subnet_v2" "subnet_1" {
        network_id = openstack_networking_network_v2.network_1.id
        cidr       = "192.168.199.0/24"
    }

    data "openstack_networking_network_v2" "external_network_1" {
        external = true
    }

    resource "openstack_networking_router_v2" "router_1" {
        name                = "router"
        external_network_id = data.openstack_networking_network_v2.external_network_1.id
    }

    resource "openstack_networking_router_interface_v2" "router_interface_1" {
        router_id = openstack_networking_router_v2.router_1.id
        subnet_id = openstack_networking_subnet_v2.subnet_1.id
    }

    resource "openstack_networking_port_v2" "port" {
        name       = "port"
        count      = 3
        network_id = openstack_networking_network_v2.network2.id

        fixed_ip {
            subnet_id = openstack_networking_subnet_v2.subnet_2.id
        }

    }

    data "openstack_images_image_v2" "image_1" {
        name        = "Ubuntu 20.04 LTS 64-bit"
        most_recent = true
        visibility  = "public"
    }

    resource "openstack_compute_instance_v2" "server" {
        name              = "server"
        count             = 3
        image_id          = data.openstack_images_image_v2.ubuntu.id
        flavor_id         = "1312"
        key_pair          = servercore_keypair_v2.keypair_1.name
        availability_zone = "ru-9a"

        network {
            port = openstack_networking_port_v2.port[count.index].id
        }

        lifecycle {
            ignore_changes = [image_id]
        }

        vendor_options {
            ignore_resize_confirmation = true
        }

    }

    resource "openstack_networking_floatingip_v2" "floatingip" {
        pool  = "external-network"
        count = 3
    }

    resource "openstack_networking_floatingip_associate_v2" "association" {
        count       = 3
        port_id     = openstack_networking_port_v2.port[count.index].id
        floating_ip = openstack_networking_floatingip_v2.floatingip[count.index].address
    }

1. Optional: configure providers⁠

If you have configured Servercore and OpenStack providers, skip this step.

Ensure that in the Control Panel you have created a service user with the Account Administrator and User Administrator roles.
Create a directory to store the configuration files and a separate file with a .tf extension to configure the providers.
Add Servercore and OpenStack providers to the file to configure the providers:
```
terraform {
  required_providers {
    servercore  = {
      source  = "terraform.servercore.com/servercore/servercore"
      version = "~> 6.0"
    }
    openstack = {
      source  = "terraform-provider-openstack/openstack"
      version = "2.1.0"
    }
  }
}
```
Here version — versions of providers. The current version of the OpenStack provider can be found in Terraform Registry and GitHub.

Learn more about the products, services, and services that can be managed with providers in the Servercore and OpenStack Providers instruction.
Initialize the Servercore provider:
```
provider "servercore" {
  domain_name = "123456"
  username    = "user"
  password    = "password"
  auth_region = "ru-9"
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3/"
}
```
Here:
- domain_name — Servercore account number. You can look it up in control panel in the upper right corner;
- username — username service user with the roles Account Administrator and User Administrator. Can be viewed in the control panel section Access Control → User Management → tab Service Users (the section is available only to the Account Owner and User Administrator);
- password — password of the service user. You can view it when creating a user or change it to a new one;
- auth_region — pool for example ru-9. All resources will be created in this pool. The list of available pools can be found in the instructions Availability matrices.
Create a project:
```
resource "servercore_project_v2" "project_1" {
  name = "project"
}
```
View a detailed description of the servercore_vpc_project_v2 resource.
Create a service user to access the project and assign the Project Administrator role to it:
```
resource "servercore_iam_serviceuser_v1" "serviceuser_1" {
  name         = "username"
  password     = "password"
  role {
    role_name  = "member"
    scope      = "project"
    project_id = servercore_project_v2.project_1.id
  }
}
```
Here:
- username — username;
- password — user password. The password must be no shorter than eight characters and contain Latin letters of different cases and digits;
- project_id — Project ID. You can view it in control panel: section Cloud Platform → open the projects menu (the name of the current project) → in the line of the required project press .
View a detailed description of the servercore_iam_serviceuser_v1 resource.

Initialize the OpenStack provider:

provider "openstack" {
  auth_url    = "https://cloud.api.selcloud.ru/identity/v3"
  domain_name = "123456"
  tenant_id   = servercore_project_v2.project_1.id
  user_name   = servercore_iam_serviceuser_v1.serviceuser_1.name
  password    = servercore_iam_serviceuser_v1.serviceuser_1.password
  region      = "ru-9"
}

Here:

domain_name — Servercore account number. You can look it up in control panel in the upper right corner;
region — pool for example ru-9. All resources will be created in this pool. The list of available pools can be found in the instructions Availability matrices.

If you create resources at the same time as configuring providers, add the depends_on argument for OpenStack resources . For example, for the resource openstack_networking_network_v2:

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"

  depends_on = [
    servercore_project_v2.project_1,
    servercore_iam_serviceuser_v1.serviceuser_1
  ]
}

Open the CLI.
Initialize the Terraform configuration in the directory:
```
terraform init
```
Check that the configuration files have been compiled without errors:
```
terraform validate
```
Format the configuration files:
```
terraform fmt
```
Check the resources that will be created:
```
terraform plan
```
Apply the changes and create the resources:
```
terraform apply
```
Confirm the creation — type yes and press Enter. The created resources are displayed in the control panel.
If there were not enough quotas to create resources, increase the quotas.

2. Add a public SSH key⁠

resource "servercore_keypair_v2" "keypair_1" {
  name       = "keypair"
  public_key = file("~/.ssh/id_rsa.pub")
  user_id    = servercore_iam_serviceuser_v1.serviceuser_1.id
}

Here public_key is the path to the public SSH key. If SSH keys are not generated, create them.

View a detailed description of the servercore_vpc_keypair_v2 resource.

3. Create a private network and subnet⁠

resource "openstack_networking_network_v2" "network_1" {
  name           = "private-network"
  admin_state_up = "true"
}

resource "openstack_networking_subnet_v2" "subnet_1" {
  name       = "private-subnet"
  network_id = openstack_networking_network_v2.network_1.id
  cidr       = "192.168.199.0/24"
}

Here cidr is the CIDR of the private subnet, for example 192.168.199.0/24.

See a detailed description of the resources:

4. Create a cloud router connected to an external network⁠

A cloud router connected to an external network acts as a 1:1 NAT for access from a private network to the Internet through the public IP address of the router.

data "openstack_networking_network_v2" "external_network_1" {
  external = true
}

resource "openstack_networking_router_v2" "router_1" {
  name                = "router"
  external_network_id = data.openstack_networking_network_v2.external_network_1.id
}

resource "openstack_networking_router_interface_v2" "router_interface_1" {
  router_id = openstack_networking_router_v2.router_1.id
  subnet_id = openstack_networking_subnet_v2.subnet_1.id
}

See a detailed description of the resources:

5. Create ports for cloud servers⁠

resource "openstack_networking_port_v2" "port" {
  name       = "port"
  count      = 3
  network_id = openstack_networking_network_v2.network2.id

  fixed_ip {
    subnet_id = openstack_networking_subnet_v2.subnet_2.id
  }
}

Here count is the number of ports.

View a detailed description of the openstack_networking_port_v2 resource.

6. Get an image⁠

data "openstack_images_image_v2" "image_1" {
  name        = "Ubuntu 20.04 LTS 64-bit"
  most_recent = true
  visibility  = "public"
}

See the detailed description of the openstack_images_image_v2 data source.

7. Create cloud servers⁠

resource "openstack_compute_instance_v2" "server" {
  name              = "server"
  count             = 3
  image_id          = data.openstack_images_image_v2.ubuntu.id
  flavor_id         = "1312"
  key_pair          = servercore_keypair_v2.keypair_1.name
  availability_zone = "ru-9a"

  network {
    port = openstack_networking_port_v2.port[count.index].id
  }

  lifecycle {
    ignore_changes = [image_id]
  }

  vendor_options {
    ignore_resize_confirmation = true
  }
}

Here:

count — number of servers;
flavor_id — The ID of the flavor. For example, 1312 — ID of a flavor with a fixed Standard Line configuration with 1 vCPU, 2048 GB RAM, 16 GB local disk. You can view the flavor list using the command openstack flavor list or in the table List of fixed configuration flavors in all pools;
availability_zone — pool segment in which cloud servers will be created, e.g. ru-9a. The list of available pool segments can be found in the instructions. Availability matrices.

See the detailed description of the openstack_compute_instance_v2 resource.

8. Create public IP addresses⁠

resource "openstack_networking_floatingip_v2" "floatingip" {
  count = 3
  pool  = "external-network"
}

Here count is the number of public IP addresses.

View a detailed description of the openstack_networking_floatingip_v2 resource.

9. Associate public and private IP addresses of cloud servers⁠

Public IP addresses will be connected to cloud server ports and associated with private IP addresses.

resource "openstack_networking_floatingip_associate_v2" "association" {
  count       = 3
  port_id     = openstack_networking_port_v2.port[count.index].id
  floating_ip = openstack_networking_floatingip_v2.floatingip[count.index].address
}

Here count is the number of associations of public and private IP addresses.

View a detailed description of the openstack_networking_floatingip_associate_v2 resource.

Configuration files⁠​

1. Optional: configure providers⁠​

2. Add a public SSH key⁠​

3. Create a private network and subnet⁠​

4. Create a cloud router connected to an external network⁠​

5. Create ports for cloud servers⁠​

6. Get an image⁠​

7. Create cloud servers⁠​

8. Create public IP addresses⁠​

9. Associate public and private IP addresses of cloud servers⁠​